/def -F -agL -mregexp -t'^An? (.*) tattoo on the (.*)\.( \(([0-9]+) uses? left\))?' tattoos_trig = \
	/let part=$[replace(" ","",{P2})] %; \
	/if ({P4} =~ "") \
		/eval /test tattoos_%part := strcat(tattoos_%part, " ", {P1}) %; \
	/else \
		/eval /test tattoos_%part := strcat(tattoos_%part, " ", {P1}, "(", {P4}, ")") %; \
	/endif %; \

/def tattoos_reset = \
	/quote -S /set `"/listvar -s tattoos_*"= %; \
	/set show_tattoos=1 %; \

/def -F -mregexp -t'^You have the following tattoos:' tattoos_trig2 = /tattoos_reset
/def -F -mregexp -t'^On .* you see:' tattoos_trig3 = /tattoos_reset

/def -E(show_tattoos=1) -Fp999 -hPROMPT show_tattoos_trig = \
	/eval /echo -p @{nCgreen}      head@{nCblue} -@{nCyellow}%tattoos_head %; \
	/eval /echo -p @{nCgreen}     torso@{nCblue} -@{nCyellow}%tattoos_torso %; \
	/eval /echo -p @{nCgreen}  left arm@{nCblue} -@{nCyellow}%tattoos_leftarm %; \
	/eval /echo -p @{nCgreen} right arm@{nCblue} -@{nCyellow}%tattoos_rightarm %; \
	/eval /echo -p @{nCgreen}  left leg@{nCblue} -@{nCyellow}%tattoos_leftleg %; \
	/eval /echo -p @{nCgreen} right leg@{nCblue} -@{nCyellow}%tattoos_rightleg %; \
	/unset show_tattoos